DATUMVERSCHIL in Excel: leeftijd en diensttijd berekenen

Wil je in Excel de leeftijd of de diensttijd van medewerkers berekenen? Met DATUMVERSCHIL tel je het aantal volledige jaren, maanden of dagen tussen twee datums. Dat is nauwkeuriger dan jaartallen van elkaar aftrekken, want de functie houdt rekening met de datum waarop iemand jarig is of in dienst kwam.

In het voorbeeld bij dit artikel staat een personeelsoverzicht met geboortedatums en datums van indiensttreding. Daarin bereken je de leeftijd, de dienstjaren en de diensttijd in jaren, maanden en dagen. Bij dit artikel kun je het voorbeeldbestand downloaden en elke stap zelf nadoen.

Waarom jaartallen aftrekken niet klopt

Vaak trek je eerst het geboortejaar af van het jaar van de peildatum:

=JAAR($B$1)-JAAR(C4)

Dat gaat goed zolang iemand dit jaar al jarig is geweest. Is de verjaardag nog niet geweest, dan telt Excel er een jaar te veel bij.

In het voorbeeld is Daan Visser geboren op 22 december 1978. Op de peildatum van 5 november 2026 is hij 47. Jaartallen aftrekken geeft 48. DATUMVERSCHIL telt alleen volledige jaren en komt wel op 47 uit.

Zo werkt DATUMVERSCHIL

De functie heeft drie argumenten:

=DATUMVERSCHIL(begindatum;einddatum;eenheid)

De begindatum is de vroegste datum, zoals een geboortedatum of de datum van indiensttreding. De einddatum is de datum waarop je wilt rekenen. Met de eenheid geef je aan wat Excel moet tellen, bijvoorbeeld “Y” voor volledige jaren. De eenheid zet je tussen aanhalingstekens.

Excel toont DATUMVERSCHIL niet in de lijst met functies en geeft geen hulp bij de argumenten. Je typt de functie dus zelf helemaal uit. Ligt de begindatum na de einddatum, dan krijg je de foutmelding #GETAL!.

Werk je met een Engelse versie van Excel? Dan heet de functie DATEDIF. Andere vertalingen vind je in het overzicht Excel formules en vertalingen.

Leeftijd berekenen in Excel

Zet eerst de peildatum in een vaste cel, bijvoorbeeld B1. Dat is de datum waarop je de leeftijd wilt weten. In het voorbeeldbestand is dat 5 november 2026, zodat de uitkomsten gelijk blijven. Wil je met de datum van vandaag rekenen, typ dan in B1:

=VANDAAG()

Staat de geboortedatum in C4, dan bereken je de leeftijd met:

=DATUMVERSCHIL(C4;$B$1;"Y")

Door de dollartekens blijft de verwijzing naar B1 staan als je de formule naar beneden doortrekt.

Diensttijd berekenen in Excel

De dienstjaren bereken je op dezelfde manier. Alleen is de datum van indiensttreding nu de begindatum:

=DATUMVERSCHIL(D4;$B$1;"Y")

Ook hier telt Excel alleen volledige jaren. Ruben Hendriks begon op 6 november 2023 en is op de peildatum één dag minder dan drie jaar in dienst. De uitkomst is dus 2. Wie korter dan een jaar in dienst is, krijgt 0.

Diensttijd in jaren, maanden en dagen

Wil je de diensttijd preciezer weten, reken dan ook de maanden en dagen uit na het laatste volle dienstjaar. De maanden bereken je met:

=DATUMVERSCHIL(D4;$B$1;"YM")

YM telt de maanden en laat de volle jaren buiten beschouwing. De dagen bereken je met:

=DATUMVERSCHIL(D4;$B$1;"MD")

MD telt de dagen na de laatste volle maand. Microsoft raadt deze eenheid af, omdat de uitkomst rond het einde van de maand niet altijd klopt. Valt een begindatum op de 29e, 30e of 31e, controleer de uitkomst dan.

De diensttijd voluit in één zin

Met het &-teken zet je de jaren, maanden en dagen achter elkaar in één zin. Staan de uitkomsten in F4, G4 en H4, dan gebruik je:

=F4&" jaar, "&G4&ALS(G4=1;" maand";" maanden")&" en "&H4&ALS(H4=1;" dag";" dagen")

De ALS-functie zorgt voor het enkelvoud bij 1 maand of 1 dag. Bij Anouk de Vries staat dan: 14 jaar, 1 maand en 19 dagen.

De eenheden van DATUMVERSCHIL

DATUMVERSCHIL kent zes eenheden:

  • “Y”: volledige jaren;
  • “M”: volledige maanden;
  • “D”: dagen, hetzelfde als einddatum min begindatum;
  • “YM”: maanden na het laatste volle jaar;
  • “MD”: dagen na de laatste volle maand;
  • “YD”: dagen na het laatste volle jaar.

In het voorbeeldbestand staan ze op het blad Eenheden. Pas daar de datums aan en je ziet direct wat elke eenheid telt.

Wanneer gebruik je DATUMVERSCHIL?

De functie is handig zodra je wilt weten hoeveel volledige jaren, maanden of dagen er tussen twee datums zitten. Denk aan:

  • de leeftijd van medewerkers op een peildatum;
  • dienstjaren voor een overzicht van jubilea;
  • de looptijd van een contract.

Leeftijd en diensttijd berekenen met één peildatum

Met DATUMVERSCHIL reken je de leeftijd en de diensttijd uit in volledige jaren en als je wilt ook in maanden en dagen. Alle formules verwijzen naar dezelfde peildatum. Wijzig je die ene datum, dan past het hele overzicht zich aan.

Wil je de opzet zelf bekijken? Download het voorbeeldbestand en volg de instructies om een bestand te maken naar je eigen voorbeeld..

Elke twee weken nieuwe tips in je mail?

We versturen de tips in een inspiratiebrief naar jou. Gratis, elke twee weken en uitschrijven kan altijd.